10 POKE53280,11:POKE53281,11:POKE788,52
20 PRINT"[147][159]                          [146]"
34 PRINT " [144]BOB KOBER[159]   FILE SCRATCH [146]  [144]AUG 9,1984[159]"
40 PRINT "                          [146][144]":IFYXTHEN90
50 DR$="0":D=VAL(DR$):QQ=1
60 DR$= "I"+DR$:OPEN 15,8,15,DR$
70 GOSUB 570
80 OPEN 1,8,3,"#":GOSUB 580
90 PRINT"  [153]'Y'[144][146]TO SCRATCH--[153]'N'[144][146]TO KEEP--[153]'Q'[144][146]TO QUIT"
100 PRINTTAB(5)"FILE NAME"SPC(11)"ACTION"
110 PRINTTAB(4)"[183][183][183][183][183][183][183][183][183][183][183]         [183][183][183][183][183][183][183][183][144]":IFQQ>1THEN150
120 Z$=CHR$(0)
130 T=18:S=1
140 IFPEEK(214)>21THENQQ=QQ+1:GOTO700
150 PRINT#15,"U1:"3;D;T;S
160 PRINT#15,"B-P:"3;2+32*R
170 GET#1,A$:IF A$="" THEN A$=Z$
180 IF ASC(A$)<129 THEN 300
190 PRINTTAB(5);
200 FOR K=5+32*R TO 20+32*R
210 PRINT#15,"B-P:"3;K
220 GET#1,A$:IF A$="" THEN PRINT" [146]";:GOTO 240
230 PRINT A$;
240 NEXT
250 PRINT"  SCRATCH ?  [146][157]";
260 GETA$:IFA$<>"Y" AND A$<>"N" ANDA$<>"Q"THEN260
270 IFA$="Q"THENCLOSE1:CLOSE15:SYS65126
280 PRINTA$;"[144]"
290 IF A$="Y" THEN GOSUB 410
300 R=R+1:IF R<8 THEN 140
310 PRINT#15,"B-P:"3;0
320 GET#1,A$:IFA$="" THENA$=Z$
330 T=ASC(A$)
340 IFT=0THENPRINT:FORI=1TO20:PRINT"[154][192] ";:FORJ=1TO20:NEXTJ,I
350 IFT=0THENPRINT"[144]           END OF DIRECTORY.":GOTO490
360 PRINT#15,"B-P:"3;1
370 GET#1,A$:IFA$=""THENA$=Z$
380 S=ASC(A$):PRINT:PRINT "*** NEXT TRACK: ";:NU=T:GOSUB660:PRINT N$;
390 PRINT TAB(20);"NEXT SECTOR: ";:NU=S:GOSUB 660:PRINT N$;" ***":PRINT
400 R=0:GOTO140
410 PRINT"    ARE YOU SURE? "
420 GETK$:IFK$=""THEN420
430 IFK$<>"Y"THENPRINT"":GOTO150
440 PRINTTAB(21)"[145] SCRATCHING FILE [146]"
450 PRINT#15,"B-P:"3;5+32*R-3
460 PRINT#1,CHR$(0);
470 PRINT#15,"U2:"3;D;T;S
480 GOSUB580:RETURN
490 CLOSE 1
500 PRINT"         VALIDATE DISK Y OR N?"
510 GET V$:IF V$="Y"THEN540
520 IF V$=""THEN 510
530 A$="Q":GOTO270
540 PRINT"          [129] VALIDATING DISK [144][146]"
550 PRINT#15,("V"+DR$)
560 GOSUB580:A$="Q":GOTO270
570 REM CHECK DISK STATUS
580 INPUT#15,ER,ER$,TR,SE
590 IF ER=0 THEN RETURN
600 CLOSE 15:CLOSE 1
610 PRINT" DISK ERROR! ";
620 PRINT ER;ER$;TR;SE
630 PRINT" CORRECT ERROR---ANY KEY TO CONTINUE"
640 GETA$:IFA$=""THEN640
650 GOTO10
660 REM FORMAT (null)S
670 N$=MID$(STR$(NU),2)
680 IF LEN(N$)<2 THEN N$="0"+N$
690 RETURN
700 PRINT"         ANY KEY TO CONTINUE "
710 GETA$:IFA$=""THEN710
720 YX=1:PRINT"[147]":GOTO20